Protocole allégé d'accès à un annuaire LDAP (v3) :
Représentation en chaîne de caractères UTF-8 des noms différenciés

Statut de ce document

Ce document spécifie un protocole standard d'Internet pour la communauté Internet, et ne sera éprouvé qu'après plusieurs discussions et suggestions. Merci de vous référer à l'édition courante du " Internet Official Protocol Standards " (STD1) pour l'état de standardisation et le statut de ce protocole. La distribution de ce document est illimitée.

Copyright

Copyright © "Internet society" (1997) - tous droits réservés.

Note d'IESG

Les mots clés "DOIT", "NE DOIT PAS", "REQUIS", "DEVRA", "NE DEVRA PAS", "DEVRAIT", "NE DEVRAIT PAS", "RECOMMANDÉ", "PEUT", et "FACULTATIF" dans ce document doivent être interprétés comme décrit dans RFC 2119 [6].

1. Arrière-plan

Cette spécification présume la connaissance de X.500 [1], et le concept du nom différencié. Il est important d'avoir un format commun pour pouvoir représenter clairement un nom différencié. Le but premier de cette spécification est de faciliter l'encodage et le décodage. Un but secondaire est d'avoir des noms qui sont lisibles par les humains. On ne s'attend pas à ce que les clients LDAP avec une interface utilisateur humaine affichent ces chaînes de caractères directement à l'utilisateur, mais exécuteraient très probablement des traductions (telles qu'exprimer les noms des types d'attribut dans une des langues nationales locales).

2. Conversion des noms différenciés ASN.1 en chaîne de caractères

Dans X.501 [2] la structure ASN.1 du nom différencié est définie comme :

   DistinguishedName ::= RDNSequence

   RDNSequence ::= SEQUENCE OF RelativeDistinguishedName

   RelativeDistinguishedName ::= SET SIZE (1..MAX) OF
    AttributeTypeAndValue

   AttributeTypeAndValue ::= SEQUENCE {
    type  AttributeType,
    value AttributeValue }

Les sections suivantes définissent l'algorithme pour convertir d'une représentation structurée par ASN.1 en une représentation chaîne de caractères UTF-8.

2.1. Transcodage du "RDNSequence"

Si le "RDNSequence" (séquence du nom différencié relatif) est une séquence vide, le résultat est la chaîne de caractères vide ou de longueur nulle.

Autrement, la sortie consiste en des encodages en chaîne de caractères de chaque RDN (nom différencié relatif) dans le "RDNSequence" (selon 2.2), commençant par le dernier élément de la séquence et en se déplaçant en arrière vers le premier.

Les encodages des noms différenciés relatifs voisins sont séparés par une virgule (',' ASCII 44).

2.2. Transcodage du RDN

En convertissant un nom différencié relatif (RDN = "RelativeDistinguishedName") ASN.1 en chaîne de caractères, la sortie consiste en des encodages en chaîne de caractères de chaque "AttributeTypeAndValue" (selon 2.3), dans n'importe quel ordre.

Là où il y a des RDN à valeurs multiples, les sorties des "AttributeTypeAndValues" voisins sont séparées par un signe plus ('+' caractère ASCII 43).

2.3. Transcodage de "AttributeTypeAndValue"

Le type et la valeur d'un attribut ("AttributeTypeAndValue") est encodé comme la représentation en chaîne de caractères du type d'Attribut, suivie du caractère égal ('=' ASCII 61), suivi de la représentation en chaîne de caractères de la valeur de l'Attribut. Le codage de la valeur de l'attribut ("AttributeValue") est donné dans la section 2.4.

Si le type de l'attribut est dans une table éditée des types d'attribut liés à LDAP [4], alors la chaîne de caractères du nom du type de cette table est utilisée, autrement il est encodé comme codage décimal pointé de l'IDENTIFICATEUR de l'OBJET du type d'attribut. La notation décimale pointée est décrite dans [3]. Comme exemple, les chaînes de caractères pour quelques-uns des types d'attribut fréquemment vus dans les RDN incluent :

Chaîne  Type d'attribut X.500
------------------------------
CN      commonName
L       localityName
ST      stateOrProvinceName
O       organizationName
OU      organizationalUnitName
C       countryName
STREET  streetAddress
DC      domainComponent
UID     userid

2.4. Transcodage d'une valeur d'attribut ASN.1 en chaîne de caractères

Si la valeur d'attribut est d'un type qui n'a pas de représentation en chaîne de caractères définie pour lui, alors il est simplement encodé comme un caractère dièse ('#' ASCII 35) suivi de la représentation hexadécimale de chacun des octets en codage BER de la valeur d'attribut X.500. Cette forme DEVRAIT être utilisée si le type d'attribut est de la forme décimale pointée.

Autrement, si la valeur d'attribut est d'un type qui a une représentation en chaîne de caractères, la valeur est convertie d'abord en chaîne de caractères UTF-8 selon sa spécification de syntaxe (voir par exemple la section 6 de [4]).

Si la chaîne de caractères UTF-8 n'a aucun des caractères suivants qui ont besoin d'être échappé, alors cette chaîne de caractères peut être utilisée comme représentation de la valeur.

• un espace ou caractère "#" se produisant au début de la chaîne de caractères
• un caractère d'espace se produisant à la fin de la chaîne de caractères
• un des caractères ",", "+", """, "\", "<", ">" ou ";"

Les implémentations PEUVENT échapper d'autres caractères.

Si un caractère à échapper est un de ceux de la liste montrée ci-dessus, alors il est préfixé par un antislash ('\' ASCII 92).

Autrement le caractère à échapper est remplacé par un antislash et deux chiffres hexadécimaux, qui forment un octet simple dans le code du caractère.

Des exemples du mécanisme d'échappement sont montrés dans la section 5.

3. Analyse d'une chaîne de caractères pour retrouver un nom différencié

La structure de la chaîne de caractères est spécifiée dans une grammaire BNF, basée sur la grammaire définie dans RFC 822 [5]. Les implantations de serveur analysant une chaîne de caractères de DN produite par un client LDAPv2 DOIVENT également accepter (et ignorer) les variantes données dans la section 4 de ce document.

distinguishedName = [nom] ; peut être la chaîne de caractères vide

name       = name-component *("," name-component)

name-component = attributeTypeAndValue *("+" attributeTypeAndValue)

attributeTypeAndValue = attributeType "=" attributeValue

attributeType = (ALPHA 1*keychar) / oid
keychar    = ALPHA / DIGIT / "-"

oid        = 1*DIGIT *("." 1*DIGIT)

attributeValue = string

string     = *( stringchar / pair )
             / "#" hexstring
             / QUOTATION *( quotechar / pair ) QUOTATION ; seulement de v2

quotechar     = <n'importe quel caractère excepté "\" ou QUOTATION >

special    = "," / "=" / "+" / "<" /  ">" / "#" / ";"

pair       = "\" ( special / "\" / QUOTATION / hexpair )
stringchar = <n'importe quel caractère excepté un des spéciaux, "\" ou QUOTATION >

hexstring  = 1*hexpair
hexpair    = hexchar hexchar

hexchar    = DIGIT / "A" / "B" / "C" / "D" / "E" / "F"
             / "a" / "b" / "c" / "d" / "e" / "f"

ALPHA      =  <toute lettre ASCII>
                                         ; (décimal 65-90 et 97-122)
DIGIT      =  <tout chiffre décimal ASCII>  ; (décimal 48-57)
QUOTATION  =  <le caractères ASCII guillemet '"' décimal 34>

4. Parenté avec RFC 1779 et LDAPv2

La syntaxe donnée dans ce document est plus restrictive que la syntaxe dans RFC 1779. Les implémentations analysant une chaîne de caractères produite par un client LDAPv2 DOIVENT accepter la syntaxe de RFC 1779. Les implémentations NE DOIVENT, cependant, produire aucun des encodages de RFC 1779 qui ne sont pas décrits ci-dessus dans la section 2.

Les implémentations DOIVENT permettre à un caractère point virgule d'être employé au lieu d'une virgule pour séparer les RDN dans un nom différencié, et DOIVENT également permettre à des caractères d'espacement d'être présents de chaque côté de la virgule ou du point virgule. Les caractères d'espacement sont ignorés, et le point virgule est remplacé par une virgule.

Les implémentations DOIVENT permettre à un oid dans le type d'attribut d'être préfixé par une des chaînes de caractères "oid." ou "OID.".

Les implémentations DOIVENT permettre aux caractères espace (' ' ASCII 32) d'être présents entre le composant nom et ',', entre le type et la valeur d'attribut et '+', entre le type d'attribut et '=', et entre '=' et la valeur d'attribut. Ces caractères d'espace sont ignorés lors de l'analyse.

Les implémentations DOIVENT permettre à une valeur d'être entourées par des guillemets ('"' ASCII 34), qui ne font pas partie de la valeur. À l'intérieur de la valeur entre guillemets, les caractères suivants peuvent apparaître sans être échappés :

",", "=", "+", "<", ">", "#" et ";"

5. Exemples

Cette notation est conçue pour être commode pour les formes communes du nom. Cette section donne quelques exemples des noms différenciés écrits en utilisant cette notation. Le premier est un nom contenant trois noms différenciés relatifs (RDN) :

CN=Steve Kille,O=Isode Limited,C=GB

Voici un exemple de nom contenant trois RDN, dans lequel le premier RDN est à valeurs multiples :

OU=Sales+CN=J. Smith,O=Widget Inc.,C=US

Cet exemple montre la méthode de citation d'une virgule dans un nom d'organisation :

CN=L. Eagle,O=Sue\, Grabbit and Runn,C=GB

Un exemple de nom dans lequel une valeur contient un caractère retour chariot :

CN=Before\0DAfter,O=Test,C=GB

Un exemple de nom dans lequel un RDN était d'un type non reconnu. La valeur est le codage BER d'une CHAÎNE DE CARACTÈRES d'OCTET contenant deux octets 0x48 et 0x69.

1.3.6.1.4.1.1466.0=#04024869,O=Test,C=GB

En conclusion, un exemple d'une valeur de nom de famille de RDN se composant des 5 lettres :

   Description Lettre Unicode      code 10646 UTF-8  Cité
   =============================== ========== ====== =======
   LATIN CAPITAL LETTER L          U0000004C  0x4C   L
   LATIN SMALL LETTER U            U00000075  0x75   u
   LATIN SMALL LETTER C WITH CARON U0000010D  0xC48D \C4\8D
   LATIN SMALL LETTER I            U00000069  0x69   i
   LATIN SMALL LETTER C WITH ACUTE U00000107  0xC487 \C4\87

Pourrait être écrit dans l'ASCII imprimable (utile pour la mise au point) :

SN=Lu\C4\8Di\C4\87

6. Références

[1] L'annuaire -- vue d'ensemble des concepts, des modèles et des services. ITU-T Rec. X.500(1993).

[2] L'annuaire -- Modèles. ITU-T Rec. X.501(1993).

[3] Wahl, M., Howes, T., et S. Kille, "Lightweight Directory Access Protocol (v3)", RFC 2251, décembre 1997.

[4] Wahl, M., Coulbeck, A., Howes, T. et S. Kille, "LDAP (v3) : Définitions de Syntaxe d'Attribut ", RFC 2252, décembre 1997.

[5] Crocker, D., "Standard of the Format of ARPA-Internet Text Messages", STD 11, RFC 822, août 1982.

[6] Bradner, S., "Key words for use in RFCs to Indicate Requirement Levels", RFC 2119.